Description

Retourne le nombre de canaux d'un fichier son.

Syntaxe

ir filenchnls ifilcod [, iallowraw]

Initialisation

ifilcod -- fichier son à interroger

iallowraw -- (facultatif) permet des fichiers son bruts (vaut 1 par défaut)

Exécution

filenchnls retourne le nombre de canaux du fichier son ifilcod. filenchnls peut retourner le nombre de canaux des fichiers de type convolve et PVOC si le paramètre iallowraw est différent de zéro (il est non nul par défaut).

Exemples

Voici un exemple de l'opcode filenchnls. Il utilise les fichiers filenchnls.csd, fox.wav et drumsSlp.wav.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o filenchnls.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

; by Menno Knevel 2022

instr 1 ; choose between mono or stereo file

ichn filenchnls  p4	            ; check number of channels
prints  "\nnumber of channels = %d\n\n", ichn

if (ichn == 1) then
    asig diskin2 p4, 1              ; mono signal	
    outs    asig, asig
else
    aL, aR diskin2 p4, 1            ; stereo signal
    outs    aL, aR
endif

endin

</CsInstruments>
<CsScore>

i 1 0 3 "fox.wav"	;mono signal
i 1 5 4 "drumsSlp.wav"	;stereo signal
e
</CsScore>
</CsoundSynthesizer>

Le fichier audio « fox.wav » est monophonique (1 canal), tandis que « drumsSlp.wav » est stéréophonique (2 canaux). Ainsi la sortie de filenchnls contiendra des lignes comme :

number of channels = 1
number of channels = 2

Voir aussi

filebit, filelen, filepeak, filesr

Crédits

Nouveau dans la version 3.57 de Csound