kr

kr — Fixe le taux de contrôle.

Description

Ces instructions sont des affectations de valeurs globales réalisées au début d'un orchestre, avant que tout bloc d'instrument ne soit défini. Leur fonction est de fixer certaines variables dont le nom est un mot réservé et qui sont nécessaires à l'exécution. Une fois fixés, ces mots réservés peuvent être utilisés dans des expressions n'importe où dans l'orchestre.

Syntaxe

kr = iarg

Initialisation

kr = (facultatif) -- fixe le taux de contrôle à iarg échantillons par seconde. La valeur par défaut est 4410.

De plus, toute variable globale peut être initialisée par une instruction de la période d'initialisation n'importe où avant la première instruction instr. Toutes les affectations ci-dessus sont exécutées dans l'instrument 0 (passe-i seulement) au début de l'exécution réelle.

Depuis la version 3.46 de Csound, on peut omettre kr. Csound utilisera les valeurs par défaut, ou calculera kr à partir des valeurs définies de ksmps et sr. Habituellement, il est mieux de ne spécifier que ksmps et sr et de laisser csound calculer kr.

Exemples

sr = 10000
kr = 500
ksmps = 20
gi1 = sr/2.
ga init 0
itranspose = octpch(.0l)

Exemples

Voici un exemple de l'opcode kr. Il utilise le fichier kr.csd.

Exemple 494. Exemple de l'opcode kr.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>

; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac         ;;  -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o kr_example.wav -W ;;; for file output any platform

; By Stefano Cucchi 2020

</CsOptions>

<CsInstruments>

sr     =        44100

kr = 4410 ; NO glitch
;kr = 10 ; Some GLITCH in kFreqMod
;kr = 2 ; Lots of GLITCH in kFreqMod
nchnls = 1
0dbfs = 1

instr 1

kenvelopemod linseg 0, 2, p4, p3-4, p4, 2, 0

kFreqMod expseg 200, p3, 800
amodulator oscil kenvelopemod, kFreqMod, 2

acarf phasor 440
ifn = 1
ixmode = 1
ixoff = 0
iwrap = 1
acarrier tablei acarf+amodulator, ifn, ixmode, ixoff, iwrap

kgenenvelop linseg 0, 0.5, 0.3, p3-1, 0.3, 0.5, 0
out acarrier * kgenenvelop

endin

</CsInstruments>

<CsScore>

f1 0 4096 10 1
f2 0 4096 10 1 0.3 0.5 0.24 0.56 0.367

i1 0 5 0.2 
e
</CsScore>

</CsoundSynthesizer>


Voir aussi

ksmps, nchnls, nchnls_i, sr