Description

Génère un glissando à partir d'un signal de contrôle.

Syntaxe

kres lineto ksig, ktime

Exécution

kres -- Signal de sortie.

ksig -- Signal d'entrée.

ktime -- Durée du glissando en secondes.

lineto ajoute un glissando (c-à-d des segments de droite) à un signal d'entrée en escalier (produit par exemple par randh ou par lpshold). Il génère un segment de droite allant d'un degré à l'autre en ktime secondes. Lorsque le degré suivant est atteint, cette valeur est maintenue jusqu'à ce qu'un nouveau degré apparaisse. Il faut s'assurer que la valeur de l'argument ktime est inférieure à l'intervalle de temps entre deux degrés consécutifs du signal original, sinon des discontinuités apparaitront dans le signal de sortie.

Lorsqu'on l'utilise avec la sortie de lpshold, on obtient une simulation de l'effet de glissando des vieux synthétiseurs analogiques.

	Note
	Une nouvelle valeur de ksig ou de ktime n'aura d'effet qu'après que la valeur précédente de ktime se soit écoulée.

Exemples

Voici un exemple de l'opcode lineto. Il utilise le fichier lineto.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o lineto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

giSine ftgen 0, 0, 2^10, 10, 1

instr 1

kfreq     randh     1000, 20, 2, 1, 2000 ;generates ten random number between 100 and 300 per second
kpan      randh     .5, 1, 2, 1, .5   ;panning between 0 and 1
kp        lineto    kpan, .5          ;smoothing pan transition
aout      poscil    .4, kfreq, giSine
aL, aR    pan2      aout, kp
          outs      aL, aR

endin
</CsInstruments>
<CsScore>

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

tlineto

Crédits

Auteur : Gabriel Maldonado

Nouveau dans la Version 4.13