Description

L'opcode maxabs prend en entrée n'importe quel nombre de signaux de taux-a ou de taux-k (tous du même taux), et retourne un signal au même taux qui est le maximum de toutes les entrées. Il est identique à l'opcode max sauf qu'il prend la valeur absolue de chaque entrée avant de les comparer. Ainsi, la sortie est toujours non-négative. Pour les signaux de taux-a, les entrées sont comparées échantillon par échantillon (c-à-d que maxabs n'examine pas une période ksmps entière du signal pour trouver son maximum local comme l'opcode max_k le fait).

Syntaxe

amax maxabs ain1, ain2 [, ain3] [, ain4] [...]

kmax maxabs kin1, kin2 [, kin3] [, kin4] [...]

Exécution

ain1, ain2, ... -- signaux de taux-a à comparer.

kin1, kin2, ... -- signaux de taux-k à comparer.

Exemples

Voici un exemple de l'opcode maxabs. Il utilise le fichier maxabs.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o maxabs.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

k1   oscili 1, 10.0, 1			;combine 3 sinusses
k2   oscili 1, 1.0, 1			;at different rates
k3   oscili 1, 3.0, 1
kmax maxabs   k1, k2, k3
kmax = kmax*250				;scale kmax
printk2 kmax				;check the values

aout vco2 .5, 220, 6			;sawtooth
asig moogvcf2 aout, 600+kmax, .5 	;change filter above 600 Hz		
     outs asig, asig

endin

</CsInstruments>
<CsScore>
f1 0 32768 10 1

i1 0 5
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

minabs, max, min, maxaccum, minaccum, maxabsaccum, minabsaccum, max_k

Crédits

Nouveau dans la version 5.01 de Csound.