Description

L'opcode min prend en entrée n'importe quel nombre de signaux de taux-a, de taux-k ou de taux-i (tous au même taux), et retourne un signal du même taux qui est le minimum de toutes les entrées. Pour les signaux de taux-a, les entrées sont comparées échantillon par échantillon (c-à-d que min n'examine pas une période ksmps entière du signal pour trouver son minimum local comme l'opcode max_k le fait).

Syntaxe

amin min ain1, ain2 [, ain3] [, ain4] [...]

kmin min kin1, kin2 [, kin3] [, kin4] [...]

imin min iin1, iin2 [, iin3] [, iin4] [...]

Exécution

ain1, ain2, ... -- signaux de taux-a à comparer.

kin1, kin2, ... -- signaux de taux-k à comparer.

iin1, iin2, ... -- signaux de taux-i à comparer.

Exemples

Voici un exemple de l'opcode min. Il utilise le fichier min.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o min.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

k1   oscili 1, 10.0, 1			;combine 3 sinusses
k2   oscili 1, 1.0, 1			;at different rates
k3   oscili 1, 3.0, 1
kmin min   k1, k2, k3
kmin = kmin*250				;scale kmin
printk2 kmin				;check the values

aout vco2 .5, 220, 6			;sawtooth
asig moogvcf2 aout, 600+kmin, .5 	;change filter around 600 Hz		
     outs asig, asig

endin

</CsInstruments>
<CsScore>

f1 0 32768 10 1

i1 0 5
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

max, maxabs, minabs, maxaccum, minaccum, maxabsaccum, minabsaccum, max_k

Crédits

Nouveau dans la version 5.01 de Csound ; taux-i ajouté dans la version 6.04