Description

Permet un signal MIDI sur 7 bit en nombres décimaux selon une échelle entre des limites minimale et maximale.

Syntaxe

idest midic7 ictlno, imin, imax [, ifn]

kdest midic7 ictlno, kmin, kmax [, ifn]

Initialisation

idest -- signal de sortie

ictlno -- numéro de contrôleur MIDI (0-127)

imin -- valeur décimale minimale de sortie définie par l'utilisateur

imax -- valeur décimale maximale de sortie définie par l'utilisateur

ifn (facultatif) -- la table à lire lorsque l'indexation est requise. La table doit être normalisée. La sortie est mise à l'échelle entre les valeurs imin et imax.

Exécution

kdest -- signal de sortie

kmin -- valeur décimale minimale de sortie définie par l'utilisateur

kmax -- valeur décimale maximale de sortie définie par l'utilisateur

midic7 (contrôle MIDI sur 7 bit au taux-i et au taux-k) permet un signal MIDI sur 7 bit en nombres décimaux mis à l'échelle entre des limites minimale et maximale. Il permet également en option une indexation de table sans interpolation. Dans midic7 les valeurs minimale et maximale peuvent varier au taux-k.

	Note
	Veuillez noter que la famille des opcodes midic est prévue pour des évènements MIDI déclenchés, et ne nécessite pas de numéro de canal car ils vont répondre au même canal que celui qui a déclenché l'instrument (voir massign). Cependant ils vont planter s'ils sont appelés depuis un évènement de partition.

Exemples

Voici un exemple de l'opcode midic7. Il utilise le fichier midic7.csd

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  -+rtmidi=virtual -M0    ;;;realtime audio out and realtime midi in 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o midic7.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
; This example expects MIDI controller input on channel 1
; run, play a note and move your midi controller 7 to see result

imax  = 1
imin  = 0
ichan = 1 
ictlno= 7 	; = midi volume

kamp	midic7	ictlno, imin, imax	
	printk2	kamp
asig	oscili	kamp, 220, 1
	outs	asig, asig

endin
</CsInstruments>
<CsScore>
; no score events allowed
f 0 20		;20 sec. for real-time MIDI events
f 1 0 4096 10 1	;sine wave

e
</CsScore>
</CsoundSynthesizer>

Voir aussi

ctrl7, ctrl14, ctrl21, initc7, initc14, initc21, midic14, midic21

Crédits

Nouveau dans la version 3.47 de Csound

Merci à Rasmus Ekman pour avoir indiqué le bon intervalle pour le numéro de contrôleur.