Description

Une simulation numérique de la configuration du filtre en échelle à diode de Moog.

Syntaxe

ares moogvcf asig, xfco, xres [,iscale, iskip]

Initialisation

iscale (facultatif, 1 par défaut) -- facteur de pondération interne. A utiliser si asig n'est pas dans l'intervalle +/-1. L'entrée est d'abord divisée par iscale, puis la sortie est multipliée par iscale. La valeur par défaut est 1. (Nouveau dans la version 3.50 de Csound).

iskip (facultatif, 0 par défaut) -- s'il est non nul, l'initialisation du filtre est ignorée. (Nouveau dans les versions 4.23f13 et 5.0 de Csound).

Exécution

asig -- signal d'entrée

xfco -- fréquence de coupure du filtre en Hz. A partir de la version 3.50, peut-être de taux-i, de taux-k ou de taux-a.

xres -- quantité de résonance. Il y a des auto-oscillations lorsque xres est proche de 1. A partir de la version 3.50, peut-être de taux-i, de taux-k ou de taux-a.

moogvcf est une simulation numérique de la configuration du filtre en échelle à diode de Moog. Cette émulation est librement basée sur le papier « Analyzing the Moog VCF with Considerations for Digital Implementation » par Stilson et Smith (CCRMA). Cette version fut codée dans Csound à l'origine par Josep Comajuncosas. Quelques modifications et conversions en C ont été apportées par Hans Mikelson.

	Avertissement
	Avant la version 6.02, ce filtre nécessitait un signal d'entrée normalisé à un. On peut l'obtenir facilement au moyen de 0dbfs, comme ceci : ares moogvcf asig, kfco, kres, 0dbfs On peut aussi utiliser moogvcf2 qui utilise comme mise à l'échelle par défaut 0dbfs.

Exemples

Voici un exemple de l'opcode moogvcf. Il utilise le fichier moogvcf.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o moogvcf.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
; iscale does not need to be set here because already 0dbfs = 1  
aout vco .3, 220, 1	; Use a nice sawtooth waveform.
kfco line 200, p3, 2000	; filter-cutoff frequency from .2 to 2 KHz
krez init p4
asig moogvcf aout, kfco, krez
     outs asig, asig

endin
</CsInstruments>
<CsScore>
;a sine wave
f 1 0 16384 10 1

i 1 0 3 .1
i 1 + 3 .7
i 1 + 3 .95
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

moogvcf2, biquad, rezzy

Crédits

Nouveau dans la version 3.49 de Csound.