pvsbandwidth

pvsbandwidth — Calcule la largeur de bande spectrale d'un signal.

Description

Calcule la largeur de bande spectrale d'un signal à partir de sa transformée de Fourier discrète.

Syntaxe

kbnd pvsbandwidth fsig

Exécution

kbnd -- la largeur de bande spectrale.

fsig -- un flot pv en entrée.

Exemples

Voici un exemple de l'utilisation de l'opcode pvsbandwidth. Il utilise le fichier pvsbandwidth.csd.

Exemple 780. Exemple de l'opcode pvsbandwidth.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-odac
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 16
nchnls = 1
0dbfs = 1

;; example written by joachim heintz 2009

giSine		ftgen		0, 0, 4096, 10, 1

instr 1
irefrtm	=		p4; time for generating new values for the spectral centroid
ifftsize	=		1024
ioverlap	=		ifftsize / 4
iwinsize	=		ifftsize
iwinshape	=		1; von-Hann window
;Sfile		=		"flute-C-octave0.wav"
Sfile		=		"fox.wav"
ain		soundin	Sfile
fftin		pvsanal	ain, ifftsize, ioverlap, iwinsize, iwinshape; fft-analysis of the audio-signal
ktrig		metro		1 / irefrtm
if ktrig == 1 then
  kcenter	pvscent	fftin; spectral center
  kbw	     pvsbandwidth fftin; spectral center
endif
aout	vco2		.2, 130
asig   butterbp  aout,kcenter,kbw
		out asig
endin

</CsInstruments>
<CsScore>
i 1 0 2.757 .3
i 1 3 2.757 .05
i 1 6 2.757 .005
i 1 9 2.757 .001
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

pvsanal, pvsynth, pvsadsyn, pvspitch

Crédits

Auteur : Victor Lazzarini
Mars 2020