sandpaper

sandpaper — Modèle semi-physique d'un son de papier de verre.

Description

sandpaper est un modèle semi-physique d'un son de papier de verre. Il fait partie des opcodes de percussion de PhISEM. PhISEM (Physically Informed Stochastic Event Modeling) est une approche algorithmique pour simuler les collisions de multiples objets indépendants produisant des sons.

Syntaxe

ares sandpaper iamp, idettack [, inum] [, idamp] [, imaxshake]

Initialisation

iamp -- Amplitude de la sortie. Note : comme ces instruments sont stochastiques, ce n'est qu'une approximation.

idettack -- période de temps durant laquelle tous les sons sont stoppés.

inum (facultatif) -- le nombre de perles, de dents, de cloches, de tambourins, etc. S'il vaut zéro, il prend la valeur par défaut de 128.

idamp (facultatif) -- le facteur d'amortissement, intervenant dans l'équation :

damping_amount = 0,998 + (idamp * 0,002)

La valeur par défaut de damping_amount est 0,999 ce qui signifie que la valeur par défaut de idamp est 0,5. Le maximum de damping_amount est 1,0 (pas d'amortissement). La valeur maximale de idamp est donc 1,0.

L'intervalle recommandé pour idamp se situe d'habitude sous les 75% de la valeur maximale.

imaxshake (facultatif) -- quantité d'énergie à réinjecter dans le système. La valeur doit être comprise entre 0 et 1.

Exemples

Voici un exemple de l'opcode sandpaper. Il utilise le fichier sandpaper.csd.

Exemple 927. Exemple de l'opcode sandpaper.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sandpaper.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

idmp = p4
a1   line 2, p3, 2			;preset amplitude increase
a2   sandpaper 1, 0.01, 128, idmp	;sandpaper needs a little amp help at these settings
asig product a1, a2			;increase amplitude
     outs asig, asig
          
endin
</CsInstruments>
<CsScore>
i1 0 1 0.5
i1 + 1 0.95

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

cabasa, crunch, sekere, stix

Crédits

Auteur : Perry Cook, fait partie de PhOLIES (Physically-Oriented Library of Imitated Environmental Sounds)
Adapté par John ffitch
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 4.07 de Csound

Notes ajoutées par Rasmus Ekman en mai 2002.