Description

La sortie audio produit un son comme si l'on secouait des maracas ou un instrument similaire de type calebasse. La méthode est inspirée d'un modèle physique développé d'après Perry Cook, mais recodé pour Csound.

Syntaxe

ares shaker kamp, kfreq, kbeans, kdamp, ktimes [, idecay]

Initialisation

idecay -- S'il est présent, indique la durée d'amortissement du shaker à la fin de la note. La valeur par défaut est zéro.

Exécution

Une note jouée sur un instrument de type maracas, avec les arguments suivants.

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note.

kbeans -- Le nombre de graines dans la calebasse. Une valeur de 8 est convenable.

kdamp -- La valeur d'amortissement du shaker. Des valeurs comprises entre 0,98 et 1 conviennent, avec une valeur raisonnable par défaut de 0,99.

ktimes -- Nombre de secousses.

	Note
	L'argument knum était redondant et a donc été supprimé dans la version 3.49.

Exemples

Voici un exemple de l'opcode shaker. Il utilise le fichier shaker.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac             ;;;RT audio out
; For Non-realtime ouput leave only the line below:
; -o shaker.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Menno Knevel

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

knum  =   p5
kfreq	line p4, p3, 440
a1 shaker .5, kfreq, 8, 0.999, knum
outs a1, a1

endin

</CsInstruments>
<CsScore>
;       frq     #
i 1 0 1 440     3
i 1 2 1 440    300
i 1 4 1 440    3000
i 1 6 2 4000    100

</CsScore>
</CsoundSynthesizer>

Crédits

Nouveau dans la version 3.47 de Csound