vibes

vibes
Précédent	Opcodes et opérateurs de l'orchestre	Suivant

Description

La sortie audio est un son de métal frappé comme sur un vibraphone. La méthode est un modèle physique développé d'après Perry Cook, mais recodé pour Csound.

Syntaxe

ares vibes kamp, kfreq, ihrd, ipos, imp, kvibf, kvamp, ivibfn, idec

Initialisation

ihrd -- la dureté de la baguette utilisé pour frapper. Compris entre 0 et 1. 0,5 est une valeur adaptée.

ipos -- l'endroit où le bloc est frappé, compris entre 0 et 1.

imp -- une table des impulsions de la frappe. Le fichier marmstk1.wav contient une fonction adéquate créée à partir de mesures et l'on peut le charger dans une table GEN01. Il est aussi disponible à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

ivfn -- forme du tremolo, habituellement une table sinus, créée par une fonction

idec -- durée avant la fin de la note lorqu'il y a une atténuation

Exécution

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note.

kvibf -- Fréquence du tremolo en Hertz. L'intervalle conseillé va de de 0 à 12.

kvamp -- Amplitude du tremolo.

Exemples

Voici un exemple de l'opcode vibes. Il utilise les fichiers vibes.csd et marmstk1.wav.

Exemple 1180. Exemple de l'opcode vibes.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     -d     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o vibes.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
ksmps = 10
nchnls = 2

; Instrument #1.
instr 1
  ; kamp = 20000
  ; kfreq = 440
  ; ihrd = 0.5
  ; ipos = p4
  ; imp = 1
  ; kvibf = 6.0
  ; kvamp = 0.05
  ; ivibfn = 2
  ; idec = 0.1
asig	vibes	20000, 440, .5, p4 , 1, 6.0, 0.05, 2, .1
	outs		asig, asig
endin


</CsInstruments>
<CsScore>

; Table #1, the "marmstk1.wav" audio file.
f 1 0 256 1 "marmstk1.wav" 0 0 0
; Table #2, a sine wave for the vibrato.
f 2 0 128 10 1

; Play Instrument #1 for four seconds.
i 1 0 4 0.561
i 1 + 4 1
e

</CsScore>
</CsoundSynthesizer>

Voir aussi

marimba

Crédits

Auteur : John ffitch (d'après Perry Cook)

Université de Bath, Codemist Ltd.

Bath, UK

Nouveau dans la version 3.47 de Csound