fin

Read signals from a file at a-rate.

Deprecated

Both the scalar and audio-array forms of fin are deprecated and remain available for older orchestras. Use diskin2 for new code.

Replacement

diskin2 returns audio through output arguments and can allocate an audio array to match the file's channels:

aChannels[] diskin2 "fox.wav", 1

When adapting an existing fin call, use the file path instead of a fiopen handle. diskin2 takes its skip position in seconds, while fin uses sample frames. Their raw-file format numbers also differ; use the values listed on the diskin2 page. At a playback rate of 1, diskin2 normally converts the file's sample rate to the orchestra's sample rate.

Syntax

fin ifilename, iskipframes, iformat, ain1 [, ain2] [, ain3] [,...]
fin ifilename, iskipframes, iformat, arr[]

Initialization

ifilename -- input file name (can be a string or a handle number generated by fiopen).

iskipframes -- number of frames to skip at the start (every frame contains a sample of each channel)

iformat -- a number specifying the input file format for headerless files.

-2 - 32 bit floating points without header
-1 - 16 bit integers without header
0 - take values from the header

Performance

fin (file input) is the complement of fout: it reads a multichannel file to generate audio rate signals. The user must be sure that the number of channels of the input file is the same as the number of ainX arguments.

Note

Please note that since this opcode generates its output using input parameters (on the right side of the opcode), these variables must be initialized before use, otherwise a 'used before defined' error will occur. You can use the init opcode for this.

Examples

Here is an example of the fin opcode. It uses the file fin.csd and fox.wav.

Example of the fin opcode.
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o fin.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

asnd init 0                     ;input of fin must be initialized
     fin  "fox.wav", 0, 0, asnd ;read audiofile
aenv follow asnd, 0.01          ;envelope follower
kenv downsamp aenv
asig rand kenv                  ;gate the noise with audiofile
     outs asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 3
e

</CsScore>
</CsoundSynthesizer>

Credits

Author: Gabriel Maldonado
Italy
1999
Author: John ffitch
NUIM, 2013

New in Csound version 3.56

Array version new in 6.01

Meaning of format parameter changed in 6.15

fin