genarray

Generate a vector (one-dimensional k-rate or i-rate array) with an arithmetic sequence.

Syntax

ModernClassic

karray = genarray(kstart, kend [, inc])
iarray = genarray(istart, iend [, inc])

karray genarray kstart, kend [, inc]
iarray genarray istart, iend [, inc]

The following expression can also be used,

array:{i,k} = [start ... ends, inc]

where start, ends, and inc are as above for genarray.

Initialization

istart -- value to place in first element.

iend -- last value to place in array.

inc -- amount to add to previous value (default 1).

Replacing tabgen

tabgen generates a k-rate array only at initialization. Replace kArray = tabgen(istart, iend, istep) with kArray = genarray(istart, iend, istep), keeping the inputs at i-rate. genarrayi explicitly selects this initialization-only form.

K-rate bounds select repeated generation during performance. Preserve the input rates when migrating so later edits to the output array are not overwritten by a newly generated sequence.

Examples

Here is an example of the genarray opcode. It uses the file genarray.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

;create and fill two arrays
iArr1[] genarray 1, 6
iArr2[] genarray 1, 6, 2/3

;print the content of iArr1
        printf  "%s", 1, "iArr1: start=1, end=6, step=default\n"
kndx    =       0
  until kndx == lenarray(iArr1) do
        printf  "iArr[%d] = %f\n", kndx+1, kndx, iArr1[kndx]
kndx    +=      1
  od

;print the content of iArr2
        printf  "%s", 1, "iArr2: start=1, end=6, step=2/3\n"
kndx    =       0
  until kndx == lenarray(iArr2) do
        printf  "iArr[%d] = %f\n", kndx+1, kndx, iArr2[kndx]
kndx    +=      1
  od

        turnoff
endin

</CsInstruments>
<CsScore>
i 1 0 1
</CsScore>
</CsoundSynthesizer>

See also

Array opcodes

Credits

Author: John ffitch
Codemist Ltd
2013

New in version 6.00