Skip to content

linsegb

Trace a series of line segments between specified absolute points.

Syntax

ares = linsegb(ia, itim1, ib [, itim2] [, ic] [...])
kres = linsegb(ia, itim1, ib [, itim2] [, ic] [...])

ares linsegb ia, itim1, ib [, itim2] [, ic] [...]
kres linsegb ia, itim1, ib [, itim2] [, ic] [...]

Initialization

ia -- starting value.

ib, ic, etc. -- value at tim1 seconds, etc.

itim1 -- time in seconds of end of first segment. A zero or negative value will cause all initialization to be skipped.

itim2, itim3, etc. -- time in seconds at the end of subsequent segments. Times must not decrease. Equal times jump to the next value.

Performance

These units generate control or audio signals whose values can pass through 2 or more specified points. The last tim value may or may not equal the instrument's performance time: a shorter performance will truncate the specified pattern, while a longer one will cause the last value to be repeated until the end of the note.

Times round to the nearest whole control period for kres or sample for ares. Points that round to the same step jump to the next value without taking an extra step.

Examples

Here is an example of the linsegb opcode. It uses the file linsegb.csd.

Example of the linsegb opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o linseg.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

giSine ftgen 0, 0, 2^10, 10, 1

instr 1

kcps = cpspch(p4)
kenv linsegb 0, 0.25, 1, 1, 0
asig poscil kenv, kcps, giSine
     outs asig, asig

endin

instr 2 ; scaling to duration

kcps = cpspch(p4)
kenv linseg 0, p3*0.25, 1, p3, 0
asig poscil kenv, kcps, giSine
     outs asig, asig

endin

</CsInstruments>
<CsScore>

i 1 0 1   7.00  ; = 1 sec, p3 fits exactly
i 1 2 2   7.00  ; = 2 sec, p3 truncated at 1 sec

i 2 4 1   7.00  ; scales to duration
i 2 6 2   7.00  ; of p3

e
</CsScore>
</CsoundSynthesizer>

See also

Linear and Exponential Generators

Credits

Author: Victor Lazzarini
June 2011

New in version 5.14