lowresx

Simulates layers of serially connected resonant lowpass filters.

Syntax

ModernClassic

ares = lowresx(asig, xcutoff, xresonance [, inumlayer] [, iskip])

ares lowresx asig, xcutoff, xresonance [, inumlayer] [, iskip]

Initialization

inumlayer -- number of filters in the stack, from 1 to 10. The default is 4.

iskip -- initial disposition of internal data space. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

Performance

asig -- input signal

xcutoff -- positive cutoff control, not in Hz.

xresonance -- positive resonance control, not in dB.

lowresx connects several lowres filters in series, all with the same cutoff and resonance. More filters give a sharper cutoff. Based on an orchestra by Hans Mikelson.

Examples

Here is an example of the lowresx opcode. It uses the file lowresx.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o lowresx.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kres = p4
inumlayer = 4

kenv linseg 0, p3*.1, 1, p3*.8, 1, p3*.1, 0     ;envelope
asig vco .3 * kenv, 220, 1                      ;sawtooth
kcut line 30, p3, 1000                          ;note: kcut is not in Hz
alx  lowresx asig, kcut, kres, inumlayer        ;note: kres is not in dB
aout balance alx, asig                          ;avoid very loud sounds
     outs aout, aout

endin
</CsInstruments>
<CsScore>
;sine wave
f 1 0 16384 10 1

i 1 0 5 1
i 1 + 5 3
i 1 + 5 20
e
</CsScore>
</CsoundSynthesizer>

See also

Standard Filters: Resonant Low-pass filters

Credits

Author: Gabriel Maldonado (adapted by John ffitch)
Italy

New in Csound version 3.49

Audio rate parameters introduced in version 6.02

November 2013.