maxarray

Returns the maximum value in a numeric array and optionally its index.

Syntax

ModernClassic

kmax [,kindx] = maxarray(karray)
imax [,iindx] = maxarray(iarray)

kmax [,kindx] maxarray karray
imax [,iindx] maxarray iarray

Performance

kmax -- variable for result.

kindx -- position (index) of result in array.

karray -- array for reading.

The array must be initialized and nonempty. The i-rate form runs once at initialization. The k-rate form reads the array on each control cycle.

The optional index is zero-based and selects the first occurrence when values tie. For a multidimensional array, it counts through all elements in storage order, with the last dimension changing fastest.

Replacing maxtab

maxtab is the deprecated k-rate name. Replace kValue, kIndex = maxtab(kArray) with kValue, kIndex = maxarray(kArray). Keep the same array and outputs. Both names use the same k-rate implementation. Only maxarray offers the i-rate form.

Examples

Here is an example of the maxarray opcode. It uses the file maxarray.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n 
</CsOptions>
<CsInstruments>
ksmps = 32
0dbfs = 1
;example by joachim heintz

           seed       0

instr 1
;create an array with 10 elements
kArr[]     init       10
;fill in random numbers and print them out
kIndx      =          0
  until kIndx == 10 do
kNum       random     -100, 100
kArr[kIndx] =         kNum
           printf     "kArr[%d] = %10f\n", kIndx+1, kIndx, kNum
kIndx      +=         1
  od
;investigate maximum number and print it out
kMax, kMaxIndx maxarray kArr
           printf     "Maximum of kArr = %f at index %d\n", kIndx+1, kMax, kMaxIndx
           turnoff
endin


</CsInstruments>
<CsScore>
i1 0 0.1
e
</CsScore>
</CsoundSynthesizer>

See also

Array opcodes

Credits

Author: John ffitch
October 2011

New in Csound version 5.14

Revised in Csound version 6.00 to work on multidimensional arrays