Skip to content

midinoteoff

Returns the key number and Note On velocity of a MIDI-activated instrument.

The current implementation behaves like midinoteonkey. It reads the Note On values that started the instrument and does not return Note Off velocity. Use midinoteonkey for these values in new code. To read incoming Note Off messages and their velocities, use midiin.

midinoteoff is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

Syntax

midinoteoff(xkey, xvelocity)

midinoteoff xkey, xvelocity

Performance

xkey -- receives the MIDI key number from the Note On message that started the instrument. For a score event, its value stays unchanged.

xvelocity -- receives the velocity from that Note On message. A later Note Off message does not replace this value. For a score event, its value stays unchanged.

If the instrument was activated by MIDI input, the opcode overwrites the values of the xkey and xvelocity with the key number and velocity from the Note On message that started the instrument. If the instrument was NOT activated by MIDI input, the values of xkey and xvelocity remain unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

📝 Adapting a score-activated Csound instrument.

See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

Examples

Here is an example of the midinoteoff opcode. It uses the file midinoteoff.csd.

Example of the midinoteoff opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    -M1 -Q1  ;;;realtime audio out and midi in and midi out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o midinoteoff.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 ;uses external midi device

kkey init 0                             ;initialize key number
kvel init 0                             ;initialize velocity
midinoteoff kkey,kvel                   ;reads the key and Note On velocity
printk2 kvel                            ;display Note On velocity when it changes
midion 1, kkey, kvel                    ;sent note to external device

endin
</CsInstruments>
<CsScore>
f 0 30  ;runs for 30 seconds    

i 1 0 2 62      ; play these notes from score as well
i 1 + 2 65
e
</CsScore>
</CsoundSynthesizer>

When you play a MIDI note, the example prints its Note On velocity. Releasing the key does not make it print the Note Off velocity. The score events leave the initialized values unchanged.

See also

midinoteonkey, midiin, MIDI/Score Interoperability

Credits

Author: Michael Gogins

New in version 4.20