Skip to content

vlowres

A bank of filters in which the cutoff frequency can be separated under user control.

Syntax

ares = vlowres(asig, kfco, kres, iord, ksep)

ares vlowres asig, kfco, kres, iord, ksep

Initialization

iord -- total number of filters (1 to 10)

Performance

asig -- input signal

kfco -- positive cutoff control for the first filter, not in Hz.

kres -- positive resonance control shared by all filters, not in dB.

ksep -- cutoff separation. Filter j, counting from zero, uses cutoff kfco * (1 + ksep*j/iord). For example, with kfco = 100, iord = 4, and ksep = 1, the cutoffs are 100, 125, 150, and 175. A separation of zero gives every filter the same cutoff. Choose ksep so that every cutoff stays positive.

vlowres connects several lowres filters in series. All filters share the same resonance, while kfco and ksep set their cutoffs.

Examples

Here is an example of the vlowres opcode. It uses the file vlowres.csd.

Example of the vlowres opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o vlowres.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1


instr 1

kamp init p4
asig vco2  kamp, 110                    ;saw wave
kfco line 30, p3, 300                   ;vary the cutoff frequency from 30 to 300 Hz.
kres = 20       
ksep = p5                               ;different resonance values
iord = p6                               ;and different number of filters
aout vlowres asig, kfco, kres, iord, ksep
aclp clip aout, 1, 1                    ;avoid distortion
     outs aclp, aclp

endin
</CsInstruments>
<CsScore>
f 1 0 16384 10 1        ;sine

s
i 1 0 10 .1 5  2        ;compensate volume and 
i 1 + 10 .1 25 2        ;number of filters = 2
s
i 1 0 10 .01 5  6       ;compensate volume and 
i 1 + 10 .04 15 6       ;number of filters = 6

e
</CsScore>
</CsoundSynthesizer>

See also

Standard Filters: Resonant Low-pass filters

Credits

Author: Gabriel Maldonado
Italy

New in Csound version 3.49