Description

Envoie des messages note on et note off sur le port MIDI OUT lorsqu'il est déclenché par une valeur différente de zéro.

Syntaxe

midion2 kchn, knum, kvel, ktrig

Exécution

kchn -- canal MIDI (1-16)

knum -- numéro de note MIDI (0-127)

kvel -- vélocité de la note (0-127)

ktrig -- signal déclencheur en entrée (normallement 0)

Identique à midion, cet opcode envoie des messages note on et note off sur le port MIDI OUT, mais seulement lorsque ktrig est différent de zéro. Cet opcode peut travailler de concert avec la sortie de l'opcode trigger.

Exemples

Voici un exemple de l'opcode midion2. Il utilise le fichier midion2.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
 -M0 -Q1 ;;;midi in and midi out
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kcps line 3, p3, .1	
klf  lfo 1, kcps, 3	;use a unipolar square to trigger
ktr  trigger klf, 1, 1	;from 3 times to .1 time per sec.
     midion2 1, 60, 100, ktr

endin
</CsInstruments>
<CsScore>

i 1 0 20
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

moscil, midion, noteon, noteoff, noteondur, noteondur2

Crédits

Nouveau dans la version 3.492 de Csound.

Merci à Rasmus Ekman pour avoir indiqué les intervalles corrects pour le canal MIDI et les numéros de contrôleur.