sfilist

sfilist — Imprime une liste de tous les instruments d'un fichier SoundFont2 (SF2) préalablement chargé.

Description

Imprime une liste de tous les instruments d'un fichier SoundFont2 (SF2) de sons échantillonnés préalablement chargé. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans la section format de fichier SoundFont2.

Syntaxe

sfilist ifilhandle

Initialisation

ifilhandle -- nombre unique généré par l'opcode sfload à utiliser comme identificateur pour un fichier SF2. On peut charger et activer plusieurs fichiers SF2 en même temps.

Exécution

sfilist imprime sur la console une liste de tous les instruments d'un fichier SoundFont2 (SF2) préalablement chargé.

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

Exemples

Voici un exemple de l'opcode sfilist. Il utilise le fichier sfilist.csd.

Exemple 949. Exemple de l'opcode sfilist.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sfilist.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; By  Menno Knevel - 2020

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gisf	sfload	"sf_GMbank.sf2"
	sfilist	gisf						;lists all instruments of Soundfont

instr 1	

inum	=	p4
ivel	=	p5
kamp	linsegr	1, 1, 1, .1, 0
kamp	= kamp/250000						;scale amplitude, small value due to 0dbfs = 1
kfreq	=	1						;do not change freq from sf
a1, a2	sfinstr3 ivel, inum, kamp*ivel, kfreq, p6, gisf        ;p6 chooses instrument, make amp velocity dependent
	outs	a1, a2
	
endin
	
</CsInstruments>
<CsScore>

i1 0 1 60 127 100       ;Halo Pad
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .

i1 5 1 60 127 1         ;Piano 2
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .

e
</CsScore>
</CsoundSynthesizer>


Sa sortie comprendra des lignes comme celles-ci :

Instrument list of "sf_GMbank.sf2"
  0) Piano 1             
  1) Piano 2             
  2) CP 70               
  3) EP 1 layer 1        
  4) EP 1 layer 2        
  5) E.Piano 2           
  6) Harpsichord              
  .......
  100) Halo Pad 
  .......

Voir aussi

sfinstr, sfinstrm, sfload, sfpassign, sfplay, sfplaym, sfplist, sfpreset

Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound