sfpassign

sfpassign — Associe tous les presets d'un fichier d'échantillons SoundFont2 (SF2) à une suite croissante d'indices numériques.

Description

Associe tous les presets d'un fichier d'échantillons SoundFont2 (SF2) préalablement chargé en mémoire à une suite croissante d'indices numériques. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans la section format de fichier SoundFont2.

sfpassign doit être placé dans le section d'en-tête d'un orchestre de Csound.

Syntaxe

sfpassign istartindex, ifilhandle[, imsgs]

Initialisation

istartindex -- indice de départ de la séquence à associer à l'ensemble des presets.

ifilhandle -- nombre unique généré par l'opcode sfload à utiliser comme identificateur pour un fichier SF2. On peut charger et activer plusieurs fichiers SF2 en même temps.

imsgs -- s'il est différent de zéro, les messages sont supprimés.

Exécution

sfpassign associe tous les presets d'un fichier d'échantillons SoundFont2 (SF2) préalablement chargé en mémoire à une suite croissante d'indices numériques, à utiliser ensuite avec les opcodes sfplay et sfplaym. istartindex indique la valeur du premier indice. On peut placer plusieurs instances de sfpassign dans la section d'en-tête d'un orchestre, chacune associant une séquence d'indices aux presets d'un fichier SF2 différent. L'utilisateur doit veiller à ce que les valeurs d'indice des preset de fichiers SF2 différents soient disjointes.

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

Exemples

Voici un exemple de l'opcode sfpassign. Il utilise le fichier sfpassign.csd.

Exemple 955. Exemple de l'opcode sfpassign.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac ;;;realtime audio out, virtual midi in
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sfpassign.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; By  Menno Knevel - 2020

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

;load three soundfonts
gisf	sfload	"sf_GMbank.sf2"
gir	sfload	"01hpschd.sf2"
giv	sfload	"07AcousticGuitar.sf2"
	sfplist gisf
	sfplist gir
        sfplist giv

; first, sf_GMbank.sf2 is loaded and assigned to start at 0 and counting up to 328
; as there are 329 presets in sf_GMbank.sf2.
; then 01hpschd.sf2 is loaded and assigned to replace the 100th preset of sf_GMbank.sf2
; then 07AcousticGuitar.sf2 is loaded and assigned to replace the 20th preset of sf_GMbank.sf2

	sfpassign	0, gisf	
	sfpassign	100, gir
        sfpassign	20, giv

instr 1	

inum	=	p4
ivel	=	p5
kamp	linsegr	1, 1, 1, .1, 0
kamp	= kamp/600000 * ivel					;scale amplitude and velocity dependent
kfreq	=	1						;do not change freq from sf
a1,a2	sfplay3	ivel, inum, kamp, kfreq, p6			;preset index starts at 0, counting up
	outs	a1, a2
	
	endin
	
</CsInstruments>
<CsScore>

i1 0 1 60 100   0   ; Piano 1 from sf_GMbank.sf2
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .

i1 5 1 60 100   100 ; harpsichord from 01hpschd.sf2
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .

i1 10 1 60 100   20 ; guitar from 07AcousticGuitar.sf2
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .

i1 15 1 60 100   101 ; Goblin from sf_GMbank.sf2
i1 + 1 62 <     .
i1 + 1 65 <     .
i1 + 1 69 10    .
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

sfilist, sfinstr, sfinstrm, sfload, sfplay, sfplaym, sfplist, sfpreset

Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound