Description

Ajoute une valeur scalaire à un vecteur dans une table.

Syntaxe

vadd_i  ifn, ival, ielements [, idstoffset]

Initialisation

ifn - numéro de la table hébergeant le signal vectoriel à traiter.

ival - valeur scalaire à ajouter.

ielements - nombre de composantes du vecteur.

idstoffset - décalage d'indexation pour la table de destination (facultatif, vaut 0 par défaut).

Exécution

vadd_i ajoute la valeur de ival à chaque composante du vecteur contenu dans la tableifn, en partant de l'index de table idstoffset. Cela permet de traiter une section particulière d'une table en spécifiant le décalage et le nombre d'éléments à traiter. Le décalage est compté à partir de 0, si bien que si aucun décalage n'est spécifié (ou s'il est fixé à 0), la table est modifiée depuis le début.

Cet opcode n'est exécuté qu'à l'initialisation. Il y a une version de taux-k de cet opcode appelée vadd.

Les valeurs négatives sont valides pour idstoffset. Les composantes du vecteur se trouvant en dehors de la table sont alors ignorées, et elles ne sont pas repliées autour de la table.

Dans tous ces opcodes, les vecteurs résultants sont stockés dans ifn, écrasant les vecteurs initiaux. Si l'on veut garder le vecteur initial, il faut utiliser vcopy ou vcopy_i pour le copier dans une autre table. Tous ces opérateurs sont conçus pour être utilisés avec d'autres opcodes qui opèrent sur des signaux vectoriels tels que vcella, adsynt, adsynt2, etc. Ils peuvent aussi être utiles en conjonction avec les opcodes spectraux pvsftw et pvsftr.

Exemples

Voici un exemple de l'opcode vadd_i. Il utilise le fichier vadd_i.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o cigoto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr=44100
ksmps=128
nchnls=2

	instr 1
ifn1 = p4
ival = p5
ielements = p6
idstoffset = p7
kval init 25
vadd_i ifn1, ival, ielements, idstoffset
	endin

	instr 2	;Printtable
itable = p4
isize = ftlen(itable)
kcount init 0
kval table kcount, itable
printk2 kval

if (kcount == isize) then
  turnoff
endif

kcount = kcount + 1 
	endin


</CsInstruments>

<CsScore>

f 1 0 16 -7 1 16 17

i2	0.0	0.2	1
i1	0.4	0.01	1	2	3	4
i2	0.8	0.2	1
i1	1.0	0.01	1	0.5	5	-3
i2	1.2	0.2	1
i1	1.4	0.01	1	1.5	10	12
i2	1.6	0.2	1
e

</CsScore>

</CsoundSynthesizer>

Voir aussi

vadd, vmult_i, vpow_i et vexp_i.

Crédits

Ecrit par Gabriel Maldonado. Arguments facultatifs ajoutés par Andrés Cabrera et Istvan Varga.

Nouveau dans Csound 5 (Auparavant seulement disponible dans CsoundAV)