vmult

vmult — Multiplication d'un vecteur dans une table par une valeur scalaire.

Description

Multiplication d'un vecteur dans une table par une valeur scalaire.

Syntaxe

vmult  ifn, kval, kelements [, kdstoffset] [, kverbose]

Initialisation

ifn - numéro de la table hébergeant le signal vectoriel à traiter.

Exécution

kval - valeur scalaire à multiplier.

kelements - nombre de composantes du vecteur.

kdstoffset - décalage d'indexation pour la table de destination (facultatif, vaut 0 par défaut).

kverbose - Indique si les avertissements sont affichés (vaut 0 par défaut).

vmult multiple chaque élément du vecteur contenu dans la table ifn par kval, à partir de l'index de table kdstoffset. Cela permet de traiter une section particulière d'une table en spécifiant le décalage et le nombre d'éléments à traiter. Le décalage est compté à partir de 0, si bien que si aucun décalage n'est spécifié (ou s'il est fixé à 0), la table est modifiée depuis le début.

Noter que cet opcode est exécuté au taux-k si bien que la valeur de kval est multipliée à chaque période de contrôle. A utiliser avec précaution si l'on ne veut pas finir avec des nombres très grands (ou utiliser vmult_i).

Ces opcodes (vadd, vmult, vpow et vexp) réalisent des opérations numériques entre un signal vectoriel de contrôle (hébergé par la table ifn), et un signal scalaire (kval). Le résultat est un nouveau vecteur qui écrase les anciennes valeurs de ifn. Tous ces opcodes travaillent au taux-k.

Les valeurs négatives sont valides pour kdstoffset. Les composantes du vecteur se trouvant en dehors de la table sont alors ignorées, et elles ne sont pas repliées autour de la table.

Si l'argument facultatif kverbose est différent de 0, l'opcode affichera des messages d'avertissement à chaque passe-k si les longueurs de table sont dépassées.

Dans tous ces opcodes, les vecteurs résultants sont stockés dans ifn, écrasant les vecteurs initiaux. Si l'on veut garder le vecteur initial, il faut utiliser vcopy ou vcopy_i pour le copier dans une autre table. Tous ces opérateurs sont conçus pour être utilisés avec d'autres opcodes qui opèrent sur des signaux vectoriels tels que vcella, adsynt, adsynt2, etc. Ils peuvent aussi être utiles en conjonction avec les opcodes spectraux pvsftw et pvsftr.

[Note] Note

Prière de noter que l'argument elements a changé dans la version 5.03 du taux-i au taux-k. Cela change le comportement de l'opcode dans le cas inhabituel où la variable de taux-i ielements est modifiée à l'intérieur de l'instrument, par exemple dans :

    instr 1
ielements  =        10
           vadd     1, 1, ielements
ielements  =        20
           vadd     2, 1, ielements
           turnoff
    endin

Exemples

Voici un exemple de l'opcode vmult. Il utilise le fichier vmult-2.csd.

Exemple 1188. Exemple de l'opcode vmult.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o cigoto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr=44100
ksmps=128
nchnls=2

	instr 1
ifn1 = p4
ival = p5
ielements = p6
idstoffset = p7
kval init 25
vmult ifn1, ival, ielements, idstoffset, 1
	endin

	instr 2	;Printtable
itable = p4
isize = ftlen(itable)
kcount init 0
kval table kcount, itable
printk2 kval

if (kcount == isize) then
  turnoff
endif

kcount = kcount + 1 
	endin


</CsInstruments>

<CsScore>

f 1 0 16 -7 1 16 17

i2	0.0	0.2	1
i1	0.4	0.01	1	2	3	4
i2	0.8	0.2	1
i1	1.0	0.01	1	0.5	5	-3
i2	1.2	0.2	1
i1	1.4	0.01	1	1.5	10	12
i2	1.6	0.2	1
e

</CsScore>

</CsoundSynthesizer>


Voici un autre exemple de l'opcode vmult. Il utilise le fichier vmult.csd.

Exemple 1189. Exemple de l'opcode vmult.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o cigoto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>


sr=44100
kr=4410
ksmps=10
nchnls=2

	instr 1 ;table playback
ar lposcil 1, 1, 0, 262144, 1
outs ar,ar
	endin

	instr 2
vcopy 2, 1, 40000 ;copy vector from sample to empty table
vmult 5, 10000, 262144 ;scale noise to make it audible
vcopy 1, 5, 40000 ;put noise into sample
turnoff
	endin

	instr 3
vcopy 1, 2, 40000 ;put original information back in
turnoff
	endin

</CsInstruments>
<CsScore>
f1  0 262144   -1 "beats.wav" 0 4 0
f2  0 262144   2  0

f5  0 262144   21  3 30000

i1 0 4
i2 3 1

s
i1 0 4
i3 3 1
s

i1 0 4

</CsScore>
</CsoundSynthesizer>


Voir aussi

vadd_i, vadd_i, vmult, vpow et vexp.

Crédits

Ecrit par Gabriel Maldonado. Arguments facultatifs ajoutés par Andrés Cabrera et Istvan Varga.

Exemple par Andrés Cabrera.

Nouveau dans Csound 5 (Auparavant seulement disponible dans CsoundAV)